Las funciones lógicas de Excel: Y, O, XO y NO
Hay muchas formas de añadir decisiones lógicas a tus hojas de Excel. Además de los operadores lógicos habituales (=, <, >, <>, <=, >=), Excel tiene funciones lógicas compuestas que evalúan varias condiciones a la vez. Las funciones Y, O, XO y NO evalúan muchas condiciones lógicas y devuelven simplemente VERDADERO o FALSO según el caso. Precisamente porque devuelven VERDADERO o FALSO, se usan mucho junto a la función SI.
La función Y de Excel
La función Y de Excel evalúa una o varias condiciones lógicas para determinar si TODAS se cumplen. Admite una o más condiciones como argumentos, separados por punto y coma, y devuelve VERDADERO si TODAS son verdaderas. En caso contrario, devuelve FALSO.
=Y(condición\_1; \[condición\_2\]; ...)
La función Y solo necesita un argumento, pero admite más (hasta 255). Los argumentos pueden ser condiciones, números, texto y referencias de celda. Si una referencia de celda está vacía, la función simplemente la ignora. Si un argumento es un número, trata el cero como FALSO y cualquier número distinto de cero (incluidos los negativos) como VERDADERO.
=Y(1<2; "hola"<>"adiós") da VERDADERO porque las dos condiciones se cumplen: 1 es menor que 2 y "hola" no es igual a "adiós".
=Y(1<2; 0) devuelve FALSO porque todos los argumentos tienen que ser VERDADERO para que la función Y devuelva verdadero. El primer argumento (1<2) es verdadero, pero el segundo, 0, equivale a FALSO, así que Y devuelve FALSO.
La función O de Excel
La función O de Excel evalúa una o varias condiciones lógicas para determinar si AL MENOS UNA se cumple. Admite una o más condiciones como argumentos, separados por punto y coma, y devuelve VERDADERO si al menos uno es verdadero. Si todos son falsos, devuelve FALSO.
=O(condición\_1; \[condición\_2\]; ...)
La función O solo necesita un argumento, pero admite hasta 255 en casi todas las versiones de Excel. Igual que Y, sus argumentos pueden ser condiciones, números, referencias de celda e incluso otras funciones Y u O. Si un argumento es un número, trata el cero como FALSO y cualquier número distinto de cero como VERDADERO. También ignora las referencias a celdas vacías.
La función O evalúa cada argumento y devuelve VERDADERO si al menos uno es verdadero.
=O(1<2; 1) devuelve VERDADERO porque los dos argumentos son verdaderos. El primero (1<2) lo es, y Excel trata el número 1 como verdadero porque no es cero.
=O(1>2; 1) también da VERDADERO. El primer argumento (1>2) es falso, pero no importa: el segundo (1) se trata como VERDADERO porque no es cero. Basta con que uno de los argumentos sea verdadero para que O devuelva verdadero.
=O(1>2; 0) devuelve FALSO porque todos sus argumentos son falsos.
La función XO de Excel
La función XO de Excel es el "O exclusivo" que, como la función O, toma condiciones y comprueba si alguna se cumple. Pero, a diferencia de O, XO devuelve VERDADERO si SOLO UNA es verdadera. Devuelve FALSO si las dos lo son y también si las dos son falsas. Si XO tiene más de dos argumentos, devuelve VERDADERO cuando un número IMPAR de ellos es VERDADERO, y FALSO cuando lo es un número PAR.
=XO(condición\_1; \[condición\_2\]; ...)
La función XO también necesita un solo argumento, pero admite hasta 255 en las versiones recientes de Excel. Igual que Y y O, acepta condiciones lógicas, números, texto, otras funciones lógicas y referencias de celda. Si una referencia está vacía, XO la ignora; el cero se trata como FALSO y cualquier número distinto de cero como VERDADERO.
=XO(1=1; "hola"="adiós") devuelve VERDADERO porque solo un argumento es verdadero. El primero (1=1) es obviamente verdadero, pero el segundo ("hola"="adiós") es claramente falso. Como solo uno se cumple, XO devuelve VERDADERO.
=XO(1=1; "hola" <> "adiós") devuelve FALSO porque hay más de un argumento verdadero. El primero (1=1) lo es, y el segundo también, porque "hola" es distinto de (<>) "adiós", así que XO devuelve FALSO. XO solo devuelve VERDADERO si se cumple UNA de las condiciones.
=XO(1=2; "hola"="adiós") también devuelve FALSO porque no se cumple ninguna. El primero (1=2) es falso y el segundo ("hola"="adiós") también.
La función NO de Excel
La función NO de Excel es probablemente la más sencilla de todas. Toma un único argumento lógico y devuelve VERDADERO o FALSO. Devuelve lo contrario del argumento: si el argumento es verdadero, NO devuelve falso, y si el argumento es falso, NO devuelve verdadero.
=NO(condición)
=NO(1=1) devolvería FALSO, porque el argumento es verdadero.
=NO(1=2) devolvería VERDADERO, porque el argumento es falso.
La función NO resulta especialmente útil cuando quieres excluir algo. Por ejemplo, imagina que tienes una hoja con viviendas y que la columna B contiene la ciudad de cada una.
| A | B | C | D | E | |
| 1 | N.º de vivienda | Ciudad | Precio | ||
| 2 | Vivienda 1 | Memphis | 300.000 | ||
| 3 | Vivienda 2 | Minneapolis | 250.000 | ||
| 4 | Vivienda 3 | Atlanta | 200.000 |
=NO(B2="Minneapolis")
Devolverá VERDADERO para cualquier vivienda cuya ciudad no sea Minneapolis, así que dará verdadero en la Vivienda 1 y la Vivienda 3, y falso en la Vivienda 2.
Combinar funciones lógicas en Excel
Ahora imagina que solo quieres excluir las viviendas unifamiliares de Minneapolis, pero conservar los demás tipos. La ciudad sigue en la columna B y el tipo de vivienda está en la columna C.
=NO(Y(B2="Minneapolis"; C2="Unifamiliar"))
| A | B | C | D | E | |
| 1 | N.º de vivienda | Ciudad | Tipo de vivienda | ||
| 2 | Vivienda 1 | Minneapolis | Apartamento | ||
| 3 | Vivienda 2 | Minneapolis | Unifamiliar | ||
| 4 | Vivienda 3 | Atlanta | Unifamiliar |
Combinar XO con Y en Excel
Imagina que te encanta ver películas nuevas y que tus favoritas son posteriores a 2015. Imagina también que te encantan las películas protagonizadas por Will Ferrell y John C. Reilly. Pero hay una pega: odias las películas de Will Ferrell y John C. Reilly rodadas después de 2015. En la tabla de abajo, donde la columna B es el actor principal, la C el actor secundario y la D el año, ¿cómo encontrarías las películas posteriores a 2015 y las de esos dos actores juntos, pero no las de esos dos actores posteriores a 2015?
| A | B | C | D | |
| 1 | Título | Actor principal | Actor secundario | Año |
| 2 | Step Brothers | Will Ferrell | John C. Reilly | 2008 |
| 3 | Uncut Gems | Adam Sandler | Idina Menzel | 2019 |
| 4 | Anchorman | Will Ferrell | Christina Applegate | 2004 |
| 5 | Holmes & Watson | Will Ferrell | John C. Reilly | 2018 |
=XO(Y(B2="Will Ferrell"; C2="John C. Reilly"); D2>2015)
Step Brothers: VERDADERO, porque Y(B2="Will Ferrell"; C2="John C. Reilly") es VERDADERO mientras que D2>2015 es FALSO.
Uncut Gems: VERDADERO, porque Y(B3="Will Ferrell"; C3="John C. Reilly") es FALSO mientras que D3>2015 es VERDADERO.
Anchorman: FALSO, porque las dos condiciones, Y(B4="Will Ferrell"; C4="John C. Reilly") y D4>2015, son FALSO.
Holmes & Watson: FALSO, porque las dos condiciones se cumplen: es una película de Will Ferrell y John C. Reilly rodada después de 2015.
¡Sigue con los ejercicios de práctica de lógica! →Imágenes referenciadas
- https://excelexercises.com/logo2.png
- https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png
