La función SI de Excel
La función SI de Excel es una función sencilla que te permite meter lógica en tus hojas. Evalúa una prueba lógica y devuelve un valor si la condición se cumple y otro distinto si no. Aprenderla te ayudará a empezar a escribir la lógica compleja que da vida a tus hojas y modelos. Por ejemplo, si una celda contiene la velocidad máxima de un vehículo, podrías escribir una función SI que devuelva el texto «rápido» si la velocidad supera los 30 y «lento» si está por debajo.
Sintaxis de la función SI
La función SI admite tres argumentos (las entradas dentro de los paréntesis, separadas por punto y coma):
=SI(condición; valor_si_verdadero; [valor_si_falso])
- condición: una afirmación o expresión, normalmente una comparación entre dos valores que da verdadero o falso. Una comparación lógica necesita uno de los operadores lógicos de la tabla de abajo.
- valor_si_verdadero: el valor que se mostrará si la condición se cumple.
- valor_si_falso: argumento opcional, el valor que mostrará la función si la condición no se cumple.
Comparaciones lógicas en Excel
Quizá te preguntes cómo escribir una comparación lógica para la primera parte de tu función SI. Para comparar dos valores, usa uno de los seis operadores de comparación de la tabla.
Puedes usar estos operadores para comparar textos, fechas, números y más.
| OPERADOR | SIGNIFICADO |
| = | Igual a |
| <> | Distinto de |
| < | Menor que |
| > | Mayor que |
| <= | Menor o igual que |
| >= | Mayor o igual que |
| COMPARACIÓN LÓGICA | RESULTADO |
| 1=1 | Verdadero |
| 1=2 | Falso |
| "Hola" <> "Adiós" | Verdadero |
| 5<>5 | Falso |
| 1/1/2021 > 1/1/2020 | Verdadero |
| 5>6 | Falso |
| 10<20 | Verdadero |
| 1/5/2020 < 1/4/2020 | Falso |
| 10<=20 | Verdadero |
| 10<=10 | Verdadero |
| 5>=1 | Verdadero |
| 5>=6 | Falso |
Usar la función SI en Excel
| A | B | C | D | E | |
| 1 | |||||
| 2 | Velocidad: | 35 | |||
| 3 | |||||
| 4 |
=SI(condición; valor_si_verdadero; valor_si_falso)
El primer argumento es la condición, la prueba lógica que compara dos valores distintos. Si se cumple, Excel devuelve el segundo argumento (valor_si_verdadero). Si no, devuelve el tercero (valor_si_falso). Mira el ejemplo:
=SI(C2>30; "Rápido"; "Lento")
La función SI de arriba compara el valor de la celda C2 con 30. Excel devuelve el texto «Rápido» si la velocidad es mayor que 30 (porque la condición se cumple) y devuelve «Lento» si NO es mayor que 30 (porque no se cumple).
También podrías omitir el tercer argumento:
=SI(C2>30; "Rápido")
Esta función mostraría la palabra «Rápido» si la velocidad fuera mayor que 30 y, en caso contrario, se quedaría simplemente en blanco, porque no tiene el argumento valor_si_falso.
Combinar SI con otras funciones de Excel
Ya has visto que una función SI puede devolver textos, pero también podemos combinar cualquier otra función de Excel con cualquiera de sus argumentos. Por ejemplo, fíjate en este ejercicio con la función SUMA: SI las ventas combinadas de Texas y California llegan al menos a 500 $, la comisión es del 10 % del total. Si no, la comisión es 0.
| A | B | C | D | E | |
| 1 | |||||
| 2 | Ventas TX: | 320 $ | |||
| 3 | Ventas CA: | 545 $ | |||
| 4 |
=SI(SUMA(C2; C3)>=500; SUMA(C2; C3)*0,1; 0)
La fórmula anterior dice: si las ventas de TX más CA son mayores o iguales que 500, devuelve el 10 % del total. Si no, devuelve 0.
Como la función SUMA de la condición devolvería 865, que es mayor que 500, nuestra función SI devolvería el argumento valor_si_verdadero. Ese argumento devuelve la suma multiplicada por 0,1, así que esta función SI devolvería 86,5.
Funciones SI anidadas
Puedes combinar tantas funciones SI como quieras «anidándolas» dentro del segundo o del tercer argumento de otra. Por ejemplo, imagina que buscas coche. Quieres uno moderno, pero también te gustan los Cadillac antiguos. Decides buscar un coche que cumpla estas condiciones:
- Si el coche es un Cadillac, cómpralo.
- Si no es un Cadillac, cómpralo solo si se fabricó después de 2010.
- Si no es un Cadillac y se fabricó en 2010 o antes, no lo compres.
| A | B | C | D | E | |
| 1 | COLOR | AÑO | MARCA | ||
| 2 | Verde | 1999 | Honda | ||
| 3 | Azul | 2009 | Cadillac | ||
| 4 | Rojo | 2015 | Chevy |
=SI(C2="Cadillac"; "Comprar"; SI(B2>2010; "Comprar"; "No comprar"))
La función de arriba dice: si la marca es «Cadillac», cómpralo. Si no, y el año es mayor que 2010, cómpralo. Si no, no lo compres.
Empezando por la fila 2, la marca no es Cadillac, así que pasamos a la cláusula valor_si_falso. El año no es mayor que 2010, así que no compraríamos el coche.
En la fila 3 la marca es Cadillac, así que sí lo compraríamos.
En la fila 4 la marca no es Cadillac, así que volvemos a la cláusula valor_si_falso. Esta vez el año sí es mayor que 2010, así que compraríamos este coche.
Usar la función SI con las funciones Y y O
Excel también te deja usar las funciones Y y O como condición de la función SI, una forma rápida de escribir varias condiciones a la vez.
Imagina que quieres que tu función SI active el argumento valor_si_verdadero solo si varias condiciones distintas se cumplen todas. La función Y admite comparaciones como argumentos y devuelve VERDADERO si TODAS se cumplen. Por ejemplo, la función =Y(A1>B1; A2=B2; A3<=B3) devolverá VERDADERO solo si los tres argumentos son verdaderos, y FALSO si alguno es falso.
Ahora imagina que quieres que tu función SI active el valor_si_verdadero si se cumple al menos una de varias condiciones. La función O también admite comparaciones como argumentos y devuelve VERDADERO si AL MENOS UNA se cumple. Por ejemplo, =O(A1>B1; A2=B2; A3<=B3) devolverá VERDADERO si al menos uno de los tres argumentos es verdadero, y FALSO solo si todos son falsos.
Para usar Y u O con una función SI, basta con sustituir el argumento de condición por la función Y u O:
=SI(Y(condición_1; [condición_2]...); valor_si_verdadero; valor_si_falso)
=SI(O(condición_1; [condición_2]...); valor_si_verdadero; valor_si_falso)
Aprende la función SI con ejemplos prácticos:
EMPEZARImágenes referenciadas
- https://excelexercises.com/logo2.png
- https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png