La función INDICE de Excel
La función INDICE de Excel sirve para devolver el valor de una celda concreta, una matriz de celdas o una referencia a celdas concretas. INDICE toma un rango de celdas y una posición, y devuelve el valor de la celda que ocupa esa posición. También puede combinarse con la función COINCIDIR para hacer búsquedas más flexibles y potentes que un simple BUSCARV.
Sintaxis de la función INDICE
La función INDICE de Excel tiene cuatro argumentos (los valores dentro de la función, separados por punto y coma) y se escribe así:
=INDICE(rango; núm_fila; [núm_columna]; [núm_área])
- Rango (obligatorio) El argumento de rango es el rango de celdas o la constante matricial que se va a indexar.
- Núm\_fila (obligatorio) El núm_fila es la posición de la fila dentro del rango o la matriz que se indexa.
- Núm\_columna (opcional) El núm_columna es la posición de la columna dentro del rango o la matriz que se indexa. Marca el cruce con el núm_fila.
- Núm\área (opcional, solo en la forma de referencia) El númárea indica cuál de los rangos o matrices referenciados se está indexando. Este argumento solo se usa cuando la fórmula incluye varios rangos o matrices.
La función INDICE en forma matricial
La forma matricial de la función INDICE solo permite referenciar una matriz (rango) y se escribe así:
=INDICE(rango; núm_fila; [núm_columna])
| A | B | C | |
| 1 | Estado | Población (millones) | Votos electorales |
| 2 | California | 39,56 | 55 |
| 3 | Texas | 28,7 | 38 |
| 4 | Florida | 21,3 | 29 |
| 5 | New York | 19,54 | 29 |
| 6 | Illinois | 12,74 | 20 |
| 7 | Pennsylvania | 12,81 | 20 |
=INDICE(A2:C7; 2; 3)
La fórmula devolvería el valor 38.
Si quisieras listar todos los valores de la tercera fila de esa matriz, usarías esta otra:
=INDICE(A2:C7; 3; 0)
La fórmula devolvería los valores: Florida \| 21,3 \| 29
La función INDICE en forma de referencia
La forma de referencia de la función INDICE permite referenciar varias matrices dentro de la misma función.
=INDICE(referencia; núm_fila; [núm_columna]; [núm_área])
Igual que en la forma matricial, el argumento núm_columna es OPCIONAL. El núm_área solo es OPCIONAL si se referencia una única matriz. Si se referencian dos o más, el núm_área es OBLIGATORIO.
| A | B | C | D | E | |
| 1 | Matriz n.º 1 | Matriz n.º 2 | |||
| 2 | Bebida | Cafeína (mg) | Bebida | Azúcar (g) | |
| 3 | Monster | 140 | Monster | 27 | |
| 4 | Rockstar | 160 | Rockstar | 29,4 | |
| 5 | Bang | 300 | Bang | 0 |
=INDICE((A3:B5; D3:E5); 3; 2; 2)
La fórmula devolvería el valor 0.
INDICE con COINCIDIR frente a BUSCARV
Como decíamos antes, el uso más habitual de INDICE es sustituir a BUSCARV. Tanto INDICE como BUSCARV son herramientas potentes para buscar dentro de una hoja de Excel, pero INDICE suele encajar mejor cuando se combina con la función COINCIDIR.
Recuerda que la forma matricial de INDICE EXIGE un argumento de referencia y un núm_fila o un núm_columna (si el núm_fila se deja en 0). Eso está muy bien si sabes exactamente qué valor buscas. Si no lo sabes, usa la función COINCIDIR.
La sintaxis de INDICE con COINCIDIR queda así:
=INDICE(rango; COINCIDIR(valor_buscado; rango_de_búsqueda; [tipo_de_coincidencia]))
| A | B | C | D | E | F | |
| 1 | Estado | Población (millones) | Votos electorales | Estado | Votos electorales | |
| 2 | California | 39,56 | 55 | Florida | ? | |
| 3 | Texas | 28,7 | 38 | |||
| 4 | Florida | 21,3 | 29 | |||
| 5 | New York | 19,54 | 29 | |||
| 6 | Illinois | 12,74 | 20 | |||
| 7 | Pennsylvania | 12,81 | 20 |
=INDICE(C2:C7; COINCIDIR(E2; A2:A7; 0))
La fórmula devolvería el valor 29.
BUSCARV haría lo mismo con esta otra fórmula:
=BUSCARV(E2; A2:C7; 3; FALSO)
Y también devolvería 29.
La mayor diferencia entre INDICE con COINCIDIR y BUSCARV es que BUSCARV necesita una columna fija (la columna 3 en nuestro ejemplo), mientras que INDICE con COINCIDIR usa una matriz (C2:C7 en el ejemplo). Si alguien añadiera una columna dentro del rango de datos, Excel no actualizaría la fórmula BUSCARV automáticamente y podría devolver información de la columna equivocada. INDICE con COINCIDIR, en cambio, garantiza que el valor sale de la columna correcta.
Excel limita BUSCARV a 255 caracteres, mientras que INDICE con COINCIDIR solo está limitada por la capacidad de tu ordenador.
Ambas tienen ventajas e inconvenientes. BUSCARV es mucho más simple y más corta, y es la mejor opción para hojas pequeñas y estáticas. INDICE con COINCIDIR es más compleja, pero garantiza que la hoja siga funcionando después de reorganizarla. Es la opción que mejor encaja en hojas de Excel grandes y cambiantes.
Aprende más sobre cómo usar INDICE con COINCIDIR aquí.Puedes leer más sobre la función BUSCARV de Excel aquí o probar algunos ejercicios de Excel con INDICE y COINCIDIR.
¡Sigue con los ejercicios de práctica de INDICE! →Imágenes referenciadas
- https://excelexercises.com/logo2.png
- https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png