Cómo cuenta CONTAR.SI las celdas que coinciden
=CONTAR.SI(A2:A100;"Este") cuenta todas las celdas del rango que sean iguales a Este. Cambia el segundo argumento por ">50" para contar números, o por "inc" para contar el texto que contenga una palabra. Una condición, un rango: eso es toda la función.La función CONTAR.SI de Excel devuelve un valor que corresponde al número de celdas que cumplen un único criterio concreto definido por ti. Puedes usar CONTAR.SI para contar cuántas celdas de un rango cumplen una condición basada en texto, comparaciones numéricas, comodines, fechas y más.
Sintaxis de la función CONTAR.SI
La función CONTAR.SI tiene dos argumentos obligatorios (valores separados por punto y coma) y se escribe así:
=CONTAR.SI(rango; criterio)
- Rango (obligatorio): el argumento rango define qué celdas se comparan con tu criterio. Excel contará cuántas celdas de ese rango cumplen el criterio indicado.
- Criterio (obligatorio): es la definición del criterio que determina qué celdas cuenta la función. Excel cuenta el número de celdas que lo cumplen.
¿Qué puede contar la función CONTAR.SI en Excel?
Como la mayoría de las funciones de Excel, CONTAR.SI solo entiende y calcula ciertos tipos de entrada. Esta es una muestra rápida de los valores que puede procesar:
- Números enteros (1, 2, 3, 4, etc.)
- Decimales (1,2; 3,45; 6,789; etc.)
- Valores negativos (-1, -2, -3, etc.)
- Porcentajes (100 %, 200 %, 35 %, etc.)
- Fracciones (3/5, 5/3, 1 2/3, etc.)
- Celdas vacías
- Valores de texto («Árbol», «The C4TS», etc.)
- Valores lógicos (VERDADERO y FALSO)
- Fechas (17/3/2020, «17 de marzo de 2020», etc.)
- Horas (2:52, 14:52, 00:14:52:55, etc.)
| Operador | Significado | |
| 1 | < | Menor que |
| 2 | > | Mayor que |
| 3 | <> | Distinto de |
| 4 | <= | Menor o igual que |
| 5 | >= | Mayor o igual que |
| Comodín | Significado | |
| 1 | ? | Comodín de un solo carácter |
| 2 | \* | Comodín de una cadena de longitud indefinida |
Ejemplos con la función CONTAR.SI
Fíjate en la siguiente tabla de Excel con datos de empleados.
| A | B | C | D | E | F | |
| 1 | Nombre del empleado | Seth Rogen | James Franco | Danny McBride | Craig Robinson | Dave Franco |
| 2 | Id. de empleado | 47 | 31 | 61 | 44 | 18 |
| 3 | Años de antigüedad | 2 | 15 | 5 | 2 | 1 |
Usar mayor que o menor que con CONTAR.SI en Excel
Si quisieras contar cuántos empleados tienen más de 2 años de experiencia, usarías esta función:
=CONTAR.SI(B3:F3; ">2")
La función devolvería 2. Poner comillas alrededor del criterio es necesario cuando usas operadores lógicos, texto o comodines en Excel. Las comillas solo sobran cuando el criterio es puramente numérico y no lleva ni operador lógico ni comodín.
Buscar coincidencias de texto con CONTAR.SI en Excel
Con la tabla anterior, si quisieras saber cuántos empleados se llaman «Craig Robinson», usarías esta función:
=CONTAR.SI(B1:F1; "Craig Robinson")
La función devolvería 1.
Ahora imagina que quieres contar los empleados cuyo apellido no sea Franco. En Excel, «<>» significa «distinto de», así que podemos combinarlo con los comodines (más sobre esto abajo) y usar CONTAR.SI para contar los empleados cuyo apellido no sea «Franco».
=CONTAR.SI(B1:F1; "<>*Franco")
La función devolvería 3, porque hay tres empleados que cumplen el criterio de no terminar en «Franco».
Buscar coincidencias numéricas con CONTAR.SI en Excel
Con la tabla anterior, si quisieras saber cuántos empleados tienen el id. 47, usarías esta fórmula:
=CONTAR.SI(B2:F2; 47)
Esta fórmula también devolvería 1.
Usar referencias de celda en la función CONTAR.SI
| A | B | C | D | E | F | |
| 1 | Nombre del producto | Naranja | Manzana | Racimo de uvas | Café Folger's | Granos de café |
| 2 | Id. de producto | 1237 | 1239 | 1245 | 3455 | 1475 |
| 3 | Costo en tienda | 0,05 $ | 0,06 $ | 0,28 $ | 0,98 $ | 1,02 $ |
| 4 | Precio de venta | 0,88 $ | 0,92 $ | 3,00 $ | 6,00 $ | 6,99 $ |
=CONTAR.SI(B3:F3; "<="&D3)
La fórmula devolvería 3. Cuando usas una referencia de celda dentro de CONTAR.SI, tienes que concatenarla con el símbolo «&».
Usar el comodín «?» con la función CONTAR.SI
El comodín «?» de Excel sustituye a un solo carácter. Por ejemplo, si quisieras saber cuántos id. de producto empiezan por «12» y tienen exactamente cuatro caracteres, usarías esta fórmula:
=CONTAR.SI(B2:F2; "12??")
Esta fórmula devolvería 3, porque hay 3 productos cuyo id. empieza por 12.
Usar el comodín «\*» con la función CONTAR.SI
El comodín «\» de Excel sustituye a cualquier cadena de caracteres. A diferencia del «?», que solo cubre un carácter, el \ cubre cualquier longitud. Si quisieras saber cuántas cadenas de la fila de productos de la tabla anterior empiezan por la letra F (sea cual sea la longitud del nombre), usarías esta fórmula:
=CONTAR.SI(B1:F1; "F*")
Esta fórmula devolvería 1, porque solo hay 1 producto cuyo nombre empieza por F.
Ahora imagina que quieres usar CONTAR.SI para contar el total de productos relacionados con el café. Puedes usar comodines para contar cuántas cadenas llevan «Café» en el nombre.
=CONTAR.SI(B1:F1; "Café")
Esta fórmula devolvería 2, porque hay dos productos cuyo nombre coincide con «\Café\». Fíjate en que el \ también puede representar la nada. En Excel, el comodín \ coincide con una cadena de cualquier longitud, incluso 0. Por eso CONTAR.SI contó los dos productos aunque en uno la palabra «Café» esté al final y en el otro al principio, sin nada antes o después.
Usar fechas con la función CONTAR.SI
La función CONTAR.SI de Excel también admite fechas en su criterio, junto con operadores de comparación, para comparar dos fechas. Fíjate en este ejemplo de un supermercado que tiene varios cupones, cada uno con un id., una fecha de caducidad y un porcentaje de descuento.
| A | B | C | |
| 1 | Id. de cupón | Fecha de caducidad | % de descuento |
| 2 | 1234 | 8/10/2020 | 25 % |
| 3 | 6518 | 20/4/2020 | 10 % |
| 4 | 6514 | 18 % | |
| 5 | 7865 | 18/4/2021 | 10 % |
| 6 | 9874 | 1/1/2021 | 10 % |
| 7 | 5566 | 20 % | |
| 6 | 1111 | 15/12/2019 | 15 % |
=CONTAR.SI(B:B; "<"&HOY())
La fórmula anterior te diría cuántos cupones de la lista han caducado a día de hoy. Si el archivo se abriera el 18 de noviembre de 2020, por ejemplo, la fórmula devolvería 3, porque hay 3 fechas de caducidad anteriores a la fecha actual. La función HOY es muy práctica porque siempre se actualiza a la fecha en que se consulta el libro, así que tu jefe podría abrirlo cualquier día del futuro y ver cuántos cupones han caducado a esa fecha.
Contar celdas en blanco con CONTAR.SI
Quizá te hayas fijado en que algunos cupones de la lista tienen la celda de la fecha de caducidad en blanco. Esos cupones, te explica tu responsable, no caducan nunca. Ahora tu tarea es contar cuántos cupones no tienen fecha de caducidad. Por suerte, CONTAR.SI también sabe contar celdas en blanco. Basta con usar dos comillas sin nada dentro para indicar un vacío en Excel.
=CONTAR.SI(B:B; "")
La fórmula anterior devuelve 2, lo que significa que hay dos cupones sin fecha de caducidad.
La familia de funciones CONTAR de Excel
La función CONTAR.SI de este tutorial es una de las muchas del grupo de funciones CONTAR. Hay otras funciones de conteo en Excel, cada una pensada para una tarea distinta.
Si solo cuentas números, usa la función CONTAR.
Si cuentas números Y texto, usa la función CONTARA.
Si cuentas celdas vacías, usa la función CONTAR.BLANCO.
Si cuentas según un único criterio, usa la función CONTAR.SI.
Si cuentas según varios criterios, usa la función CONTAR.SI.CONJUNTO.
¡Sigue con los ejercicios de práctica de CONTAR.SI! →Imágenes referenciadas
- https://excelexercises.com/logo2.png
- https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png