Función SUMAR.SI

La función SUMAR.SI de Excel

La función SUMAR.SI de Excel se usa para sumar todos los valores de un rango que indiques, siempre que el valor cumpla el criterio que definas. Ese criterio puede evaluarse contra fechas, números y cadenas de texto.

	A	B	C	D
1	Address	City	Value (thousands)	Units
2	123 Balboa Ave	San Diego	400	1
3	999 Main St	San Francisco	600	2
4	456 Ave A	Los Angeles	450	1
5	555 La Jolla Blvd	San Diego	650	4
6	999 Ave E	Los Angeles	350	3
7	111 Ave A	Los Angeles	400	2

Sintaxis de la función SUMAR.SI

La función SUMAR.SI tiene dos argumentos obligatorios (valores separados por punto y coma) y uno opcional, y se escribe así:

=SUMAR.SI(rango; criterio; [rango_suma])

Rango (obligatorio): el rango de celdas que se evalúa con el criterio. Cada celda del rango puede contener un número, una fecha o una cadena de texto.
Criterio (obligatorio): un número, una expresión, una referencia, un texto o una función que define si el rango se suma o no. El criterio admite operadores lógicos (>, <, <>, =) y comodines (?, \*).
Rango de suma (opcional): el rango de celdas que se va a sumar. Si lo omites, se sumará el propio argumento de rango. Es OPCIONAL y solo se usa cuando el rango que quieres sumar es distinto del que se evalúa con el criterio.

Nota: el rango_suma debería tener el mismo tamaño y la misma forma que el rango. Si es más grande, la fórmula sumará un rango de celdas del mismo tamaño que el definido en el argumento de rango.

¿Qué suma la función SUMAR.SI en Excel?

La función SUMAR.SI puede usar operadores lógicos para evaluar las coincidencias. Estos son sus significados:

	Operador	Significado
1	<	Menor que
2	>	Mayor que
3	<>	Distinto de
4	<=	Menor o igual que
5	>=	Mayor o igual que

La función SUMAR.SI también usa los comodines de Excel para evaluar coincidencias. Estos son sus significados:

	Comodín	Significado
1	?	Comodín de un solo carácter
2	\*	Comodín de una cadena de longitud indefinida

Como ves, los comodines de Excel son el signo de interrogación (?) y el asterisco (\). Si necesitas usar un signo de interrogación o un asterisco literales, pon una virgulilla (~) antes del símbolo (~?) (~\).

Ejemplos con la función SUMAR.SI

Fíjate en esta tabla de Excel con las ventas de los empleados.

	A	B	C
1	Empleado	N.º de venta	Total de ventas ($)
2	Simon	1	86
3	Martha	2	77
4	George	3	53
5	Mark	4	40
6	Isabella	5	80
7	Mark	6	49

Imagina que quieres el total de todas las ventas de más de 50 $. Podrías usar esta fórmula:

=SUMAR.SI(C2:C7; ">50")

La fórmula devolvería 296 $. Fíjate en que el operador de comparación va entre comillas.

¿Y si quisieras la suma de todas las ventas de Mark? Podrías usar esta fórmula, que aprovecha el argumento opcional rango_suma:

=SUMAR.SI(A2:A7; "Mark"; C2:C7)

Estamos evaluando las celdas del primer rango con el criterio y sumando los valores correspondientes del rango de suma. Así que esta fórmula hallaría la suma de todas las ventas donde el empleado sea «Mark», con lo que obtendríamos 89.

Usar referencias de celda en la función SUMAR.SI

La función SUMAR.SI puede comparar las celdas del rango con otras celdas de tu hoja. Para usar un operador lógico o un comodín con una referencia de celda, tienes que poner el operador entre comillas y concatenar la celda de comparación con el símbolo &.

	A	B	C	D	E	F
1	Sección	Artículo	Precio ($)		Precio de comparación ($):	1,05
2	Frutería	Cebolla	0,03
3	Frutería	Manzana	0,02
4	Frutería	Pera	0,05
5	Charcutería	Pechuga de pollo	0,22
6	Charcutería	Pizza grande	2,05
7	Charcutería	Sándwich de jamón	1,52

Si quisieras la suma de los precios menores que el precio de comparación de la celda F1, usarías esta fórmula:

=SUMAR.SI(C2:C7; "<"&F1)

La fórmula devolvería 0,32, que es la suma de todos los precios menores que 1,05.

Usar fechas en la función SUMAR.SI

La función SUMAR.SI admite fechas con formato válido de Excel en el argumento de criterio.

	A	B	C	D	E	F
1	N.º de carrera	Fecha	Distancia (millas)		Fecha de comparación:	22 de febrero de 2020
2	1	20 de febrero de 2020	6,3
3	2	21 de febrero de 2020	4,5
4	3	22 de febrero de 2020	7,1
5	4	22 de febrero de 2020	7,0
6	5	24 de febrero de 2020	5,6
7	6	24 de febrero de 2020	7,3

Imagina que quieres la distancia total que corriste en una fecha concreta indicada en la celda F1.

=SUMAR.SI(B2:B7; F1; C2:C7)

La fórmula sumaría todas las millas que corriste el 22 de febrero y devolvería 14,1.

Otra forma de obtener el mismo resultado es usar la función FECHA de Excel. Este ejemplo también devuelve 14,1:

=SUMAR.SI(B2:B7; FECHA(2020; 2; 22); C2:C7)

Aparte del uso de la función FECHA, la diferencia entre las dos fórmulas es que la segunda no usa una referencia de celda. La primera toma una celda como criterio, mientras que la segunda exige escribirlo dentro de la función FECHA. Al procesar grandes cantidades de datos, sobre todo si los ha escrito una persona, usar la función FECHA garantiza que todo esté en el formato de fecha que Excel necesita.

Usar comodines de Excel con la función SUMAR.SI

La función SUMAR.SI admite comodines (\, ?) dentro del argumento de criterio. El comodín \ sustituye a cualquier secuencia de caracteres, sea de la longitud que sea, mientras que el ? sustituye a un solo carácter.

	A	B	C
1	Empleado	N.º de venta	Total de ventas ($)
2	Andrew Wills	1	86
3	Michael Wills	2	77
4	Jack	3	53
5	Mike	4	40
6	Mark Hering	5	80

Imagina que quieres el total de ventas de todos los empleados con el apellido «Wills» de la tabla. Usarías esta fórmula:

=SUMAR.SI(A2:A6; "* Wills"; C2:C6)

Esta fórmula devolvería 163.

Con la misma tabla, imagina que quieres el total de ventas de todos los empleados cuyo nombre tenga cuatro caracteres. Usarías esta fórmula:

=SUMAR.SI(A2:A6; "????"; C2:C6)

La fórmula devolvería 93 $.

¡Sigue con los ejercicios de práctica de SUMAR.SI! →