So extrahierst du das letzte Wort aus einem Text in Excel

Wenn du lange genug mit Excel arbeitest, wirst du irgendwann auf Texte unterschiedlicher Länge stoßen und wissen wollen, wie du nur das letzte Wort extrahieren kannst, egal wie lang der Text ist. Zwar verfügt Excel über keine integrierte Funktion zum Extrahieren des letzten Wortes aus einem Text, doch können wir verschiedene Excel-Funktionen kombinieren, um eine Formel zu erstellen, die ausschließlich das letzte Wort zurückgibt. Wir gehen den Vorgang zum Erstellen dieser Formel Schritt für Schritt durch, aber du kannst auch direkt zum Ende springen und die vollständige Formel kopieren, wenn du es eilig hast!

Beachte, dass es in diesem Artikel darum geht, das letzte Wort aus einem Text in Excel zu extrahieren; wir haben auch einen Artikel über das Extrahieren des ersten Wortes aus einem Text, wofür ein anderer Ansatz erforderlich ist.

Erste Schritte

Nehmen wir zum Beispiel an, du hast diese Tabelle mit den Namen ehemaliger Präsidenten. Du möchtest mit einer einzigen Excel-Formel nur den Nachnamen jedes Präsidenten extrahieren.

Wir können diese Formel in mehrere Schritte unterteilen: Zuerst ermitteln wir die Funktionen, die wir verwenden müssen, und kombinieren sie dann zu einer einzigen Formel.

Die RECHTS-Funktion

Wir fangen mit der RECHTS-Funktion an. Die RECHTS-Funktion in Excel gibt eine bestimmte Anzahl der Zeichen ganz rechts aus einer Textzeichenfolge zurück. Wir müssen diese Funktion verwenden, da das letzte Wort in einer Textzeichenfolge die Zeichen ganz rechts sind.

=RECHTS(text; [number_of_characters])

text (erforderlich): Das Argument „text“ ist der Text, aus dem wir die Zeichen ganz rechts extrahieren möchten. Wir können den Text direkt in die Klammern (in Anführungszeichen) eingeben oder eine Zellreferenz zu einer Zelle angeben, die Text enthält. Dieses Argument ist erforderlich.
number\_of\_characters (erforderlich): Das Argument „number\_of\_characters“ ist optional (wir werden es aber verwenden) und gibt an, wie viele Zeichen von der rechten Seite des Textes zurückgegeben werden sollen. Wenn du für dieses Argument den Wert 5 verwendest, gibt die Formel die letzten fünf Zeichen des Textes zurück. Ohne dieses Argument gibt die Funktion einfach das Zeichen ganz rechts im Text zurück.

Probier das mal aus: Doppelklick in Zelle D2 und gib die folgende Formel ein: =RECHTS(A2; 5)

Die Formel sollte das Ergebnis „Trump“ liefern.

Donald Trump .......54321

Diese Formel funktioniert also, um das letzte Wort zu extrahieren, aber nur, wenn das letzte Wort fünf Zeichen lang ist! Bei Clinton oder bei einem der beiden Bushs funktioniert die Formel nicht. Bei Clinton würde die Formel „inton“ zurückgeben, bei George W. und George H. W. Bush hingegen „Bush“ (mit dem führenden Leerzeichen). Wie können wir festlegen, welchen Wert wir für das Argument „number\_of\_characters“ verwenden müssen, damit Excel nur das letzte Wort aus dem Text extrahiert?

Hier kommt die FINDEN-Funktion ins Spiel.

Die FINDEN-Funktion

Die FINDEN-Funktion in Excel gibt die Position des gesuchten Zeichens oder Textes innerhalb einer längeren Textzeichenfolge zurück. Um das letzte Wort aus einem Text zu extrahieren, müssen wir wissen, wo die Leerzeichen stehen, denn Leerzeichen trennen Wörter!

Die FINDEN-Funktion funktioniert so:

=FINDEN(search_for; text)

search\_for (erforderlich): Das Argument „search\_for“ ist das Zeichen oder die kürzere Zeichenfolge (Teilzeichenfolge) des Textes, nach dem du suchst. In unserem Beispiel wäre das ein Leerzeichen.
text (erforderlich): Das Argument „text“ ist die längere Textzeichenfolge, die wir durchsuchen, um das Argument „search\_for“ zu finden.

Um also den Abstand in „Bill Clinton“ zu ermitteln, kannst du in der obigen Beispieltabelle auf Zelle D5 doppelklicken und die folgende Formel eingeben: =FINDEN(" "; A5)

Excel gibt den Wert 5 zurück, da das Leerzeichen das fünfte Zeichen in „Bill Clinton“ ist.

Bill Clinton 12345

Jetzt müssen wir herausfinden, wie viele Zeichen die Funktion „RECHTS“ zurückgeben soll - also wie lang das letzte Wort ist, das du aus dem Text extrahieren möchtest?

Dazu müssen wir auch die LÄNGE-Funktion verwenden.

Die LÄNGE-Funktion

Die LÄNGE-Funktion in Excel gibt die Länge einer Textzeichenfolge in Zeichen an. So funktioniert sie:

=LÄNGE(text)

text (erforderlich): Das Argument „text“ ist der Text, dessen Länge du ermitteln möchtest. Die Länge des letzten Wortes entspricht also der Gesamtlänge des Textes abzüglich der Position des Leerzeichens.

Um die Länge von „Obama“ in „Barack Obama“ zu ermitteln, würdest du die folgende Formel verwenden: =LÄNGE(A3)-FINDEN(" "; A3)

Die Länge von „Barack Obama“ beträgt 12, und die Position des Leerzeichens ist 7, also ergibt sich 12-7 oder 5 - das ist die Länge des letzten Wortes, „Obama“.

Kombination der Funktionen zum Extrahieren des letzten Wortes

Wir wissen nun, dass wir mit der Funktion RECHTS die Zeichen ganz rechts aus einem Text in Excel extrahieren können und dass wir mit einer Kombination aus den Funktionen LÄNGE und FINDEN ermitteln können, wie lang das letzte Wort im Text ist. Wir können die Funktionen kombinieren, um das letzte Wort aus „Bill Clinton“ mit der folgenden Formel zu extrahieren. Doppelklicke in Zelle D5 in der obigen Beispieltabelle und gib Folgendes ein:

=RECHTS(A5; LÄNGE(A5)-FINDEN(" "; A5))

Diese Formel gibt erfolgreich „Clinton“ zurück und kann auch in andere Zellen kopiert werden. Dir fällt vielleicht auf, dass die Formel auch „W. Bush“ und „H. W. Bush“ zurückgibt, da die FINDEN-Funktion das erste Leerzeichen erfasst, das sie findet, und den gesamten Text rechts davon zurückgibt. Mit anderen Worten: Diese Formel funktioniert nur, wenn der Text genau ein Leerzeichen enthält, da sie dann alles rechts vom ersten Leerzeichen zurückgibt.

Wenn wir jedoch das letzte Wort aus einem Text extrahieren wollen, dessen Länge variiert, müssen wir alles rechts vom letzten Leerzeichen zurückgeben, nicht vom ersten.

Die WECHSELN-Funktion

Um das letzte Leerzeichen zu finden und so das letzte Wort aus einem Text in Excel zu extrahieren, müssen wir eine weitere Funktion einführen. Die WECHSELN-Funktion in Excel macht genau das, was du vermutest - sie ersetzt einen Text durch einen anderen. So funktioniert sie:

=WECHSELN(text; old_text; new_text; [nth_appearance])

text (erforderlich): Das Argument „text“ ist erforderlich; dies ist der Text, nach dem wir suchen, um das Argument „old\_text“ zu ersetzen.
old\_text (erforderlich): Das Argument „old\_text“ ist erforderlich und bezeichnet den Text, den wir ersetzen möchten.
new\_text (erforderlich): Das Argument „new\_text“ ist ebenfalls erforderlich und bezeichnet den Text, durch den wir „old\_text“ ersetzen möchten.
nth\_appearance (optional): Das Argument „nth\_appearance“ ist optional und legt fest, welche „old\_text“-Zeichenfolge ersetzt werden soll, wenn sie mehr als einmal im Text vorkommt.

Um die Gesamtzahl der Leerzeichen zu ermitteln, können wir die Gesamtlänge des Textes nehmen und davon die Länge desselben Textes ohne Leerzeichen abziehen. Wie könnten wir das machen? Mit der folgenden Formel: =LÄNGE(A2)-LÄNGE(WECHSELN(A2;" ";""))

Diese Formel besagt: (Länge des Textes in Zelle A2) minus (Länge des Textes in Zelle A2, wenn wir die Leerzeichen durch Leere ersetzen würden).

Sobald wir wissen, wie viele Leerzeichen es gibt, wollen wir sie durch etwas ersetzen, das wir später wiederfinden können:

=WECHSELN(A1;" ";"REPLACE ME";LÄNGE(A2)-LÄNGE(WECHSELN(A2;" ";"")))

Diese Formel ersetzt das letzte Leerzeichen durch den Text „ERSETZEN ME“ (sollte dein Text aus irgendeinem seltsamen Grund tatsächlich die Wörter „ERSETZEN ME“ enthalten, solltest du natürlich etwas anderes wählen).

=FINDEN("REPLACE ME"; WECHSELN(A2;" ";"REPLACE ME";LÄNGE(A2)-LÄNGE(WECHSELN(A2;" ";""))))

Versuch mal, diese Formel in die Excel-Tabelle oben zu kopieren - sie gibt die Position des letzten Leerzeichens in dem Text zurück, der in der Zelle steht, auf die sie verweist. Wir sind fast fertig!

Jetzt müssen wir nur noch die Zeichen ganz rechts vom letzten Leerzeichen bis zum Ende des Textes zurückgeben!

Alles zusammenfassen, um das letzte Wort aus einem Text in Excel zu extrahieren

Da wir nun die Funktion „RECHTS“ kennen und die Position des letzten Leerzeichens in einem beliebigen Text ermitteln können, brauchen wir nur noch die Zeichen ganz rechts, deren Länge der Gesamtlänge minus der Position des letzten Leerzeichens entspricht.

=RECHTS(A2; (LÄNGE(A2) - FINDEN("REPLACE ME"; WECHSELN(A2;" ";"REPLACE ME";LÄNGE(A2)-LÄNGE(WECHSELN(A2;" ";""))))))

Hoffentlich bist du noch dabei! Du kannst diese Formel kopieren und in die Excel-Tabelle oben doppelklicken - dann gibt diese Formel das letzte Wort eines beliebigen Textes zurück.

\#WERT!-Fehler, wenn der Text kein Leerzeichen enthält

Es gibt nur ein Problem: Wenn du auf eine Zelle verweist, die Text ohne Leerzeichen enthält, bekommst du eine Fehlermeldung, weil die FINDEN-Funktion nach einem Leerzeichen sucht. Um das zu beheben, ist noch ein letzter Schritt nötig.

Mit der WENNFEHLER-Funktion in Excel kannst du eine Formel erstellen, die dann einen bestimmten Wert zurückgibt, falls die Formel einen Fehler ergibt. Das sieht so aus:

=WENNFEHLER(try_this; do_this_if_error)

Das Argument „try\_this“ ist die Formel, die du ausprobieren möchtest, und „do\_this\_if\_error“ ist das, was die Funktion zurückgibt, wenn bei „try\_this“ ein Fehler auftritt.

Wenn unsere obige Formel einen Fehler ausgibt, weil der Text, auf den sie sich bezieht, kein Leerzeichen enthält, bedeutet das, dass es sich nur um ein Wort handelt - und damit auch um das letzte Wort! Wir wollen also unsere Formel auf den Text in einer bestimmten Zelle anwenden und einfach den Text dieser Zelle zurückgeben, wenn er kein Leerzeichen enthält.

Alle Funktionen kombinieren, um das letzte Wort zu extrahieren

Jetzt haben wir uns mit Text unterschiedlicher Länge beschäftigt und wissen, wie man mit Fehlern umgeht. Lass uns unsere Formel in eine WENNFEHLER-Funktion einfügen, damit sie mit jedem Text funktioniert.

Hier ist die fehlerfreie Methode, um in Excel das letzte Wort aus einem Text zu extrahieren, wobei A2 die Zelle ist, die den Text enthält, aus dem du das letzte Wort extrahieren möchtest:

=WENNFEHLER(RECHTS(A2; (LÄNGE(A2) - FINDEN("REPLACE ME"; WECHSELN(A2;" ";"REPLACE ME";LÄNGE(A2)-LÄNGE(WECHSELN(A2;" ";"")))))); A2)

Diese Formel weist Excel an, die Zeichen ganz rechts im Text vom letzten Leerzeichen bis zum Ende des Textes zurückzugeben. Die Formel ist lang und umständlich, aber am besten verstehst du sie, wenn du in einer echten Tabelle damit herumprobierst und dich mit ein paar Übungsaufgaben selbst daran versuchst.

Für weitere Excel-Übungen schau dir Excel-Übungen an.

Weiter zu den Übungsaufgaben zur LINKS-Funktion! →

Verwendete Bilder

https://excelexercises.com/logo2.png
https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png