Die Excel-Funktion „WENNS“
Die WENNS-Funktion in Excel ähnelt der WENN-Funktion, da du damit Anweisungen schreiben kannst, die einen bestimmten Wert zurückgeben, wenn eine Bedingung wahr ist. Im Gegensatz zur WENN-Funktion, die nur eine einzige Bedingung prüft, kannst du mit der WENNS-Funktion jedoch eine lange Liste von Bedingungen (bis zu 127) prüfen und den Wert zurückgeben, der der ersten wahren Bedingung zugeordnet ist.
Die WENNS-Funktion ist eine gute Alternative zur Verwendung mehrerer verschachtelter WENN-Anweisungen, da sich die verschiedenen Bedingungen und Rückgabewerte damit leichter übersichtlich darstellen lassen.
Syntax der WENNS-Funktion
Die WENNS-Funktion kann bis zu 127 Paare aus Bedingungen und Werten verarbeiten.
=WENNS(condition_1; value_if_true_1; [condition_2; value_if_true_2; ...])
- condition\_1 (erforderlich): Dies ist eine logische Aussage, die zu „wahr“ oder „falsch“ ausgewertet wird. Ein logischer Vergleich erfordert einen der logischen Operatoren.
- value\_if\_true\_1 (erforderlich): Dies ist der Wert, den die WENNS-Funktion zurückgibt, wenn condition\_1 wahr ist.
Bedingungen und Werte müssen als Paare angegeben werden. Mit anderen Worten: Das eine geht nicht ohne das andere. Wenn deine Formel „Bedingung_2“ enthält, muss sie auch „Wert_wenn_wahr_2“ enthalten, sonst gibt Excel eine Fehlermeldung aus.
So funktioniert die WENNS-Funktion
Die WENNS-Funktion wertet jede Bedingung der Reihe nach aus, bis sie eine wahre Bedingung findet. Dann gibt sie den Wert „_if_true“ zurück, der der ersten gefundenen wahren Bedingung zugeordnet ist.
Zum Beispiel wird zunächst die Bedingung_1 ausgewertet. Ist sie wahr, gibt die Funktion den Wert_if_true_1 zurück. Ist die Bedingung_1 falsch, wird anschließend die Bedingung_2 ausgewertet und so weiter.
Um die WENNS-Funktion oder andere logische Funktionen in Excel nutzen zu können, brauchst du ein gutes Verständnis der logischen Operatoren in Excel, die die Grundlage für Bedingungen bilden, die mit „wahr“ oder „falsch“ ausgewertet werden.
Übungsaufgaben zur WENNS-Funktion
Nehmen wir an, wir nutzen Excel, um die Anzahl der von jedem Mitarbeiter abgeschlossenen Geschäfte zu erfassen, und die Mitarbeiter können je nach Anzahl der abgeschlossenen Geschäfte unterschiedliche Boni erhalten. Dein Chef bittet dich, eine Excel-Formel zu erstellen, die den Bonus für jeden Mitarbeiter berechnet.
Beispiele für die WENNS-Funktion
Dein Chef sagt dir, dass jeder Mitarbeiter, der weniger als 3 Geschäfte abschließt, überhaupt keinen Bonus bekommt. Jeder, der 3 oder mehr Geschäfte abschließt, bekommt 200 $. Jeder Mitarbeiter, der 4 oder mehr Geschäfte abschließt, bekommt 500 $. Und schließlich erhält jeder Mitarbeiter, der 5 oder mehr Geschäfte abschließt, einen Bonus von 1.000 $. Ein Mitarbeiter kann einen Bonus erhalten, aber nicht mehrere.
Doppelklicke in Zelle D2 (Spalte D, Zeile 2) in der obigen Excel-Beispieltabelle und gib die folgende Formel ein:
=WENNS(C2>=5; 1000; C2>=4; 500; C2>=3; 200; C2<3; 0)
Die Formel gibt den Wert 500 zurück. Warum? Excel hat zunächst geprüft, ob der Wert in Zelle C2 (nämlich 4) größer oder gleich 5 ist. Da die Bedingung falsch ist, wird die nächste Bedingung geprüft: Ist der Wert in Zelle C2 größer oder gleich 4? Diesmal ist die Bedingung wahr, daher gibt die Formel den Wert 500 zurück.
Warum haben wir die Bedingungen und Wertepaare also vom größten zum kleinsten Wert aufgeschrieben? Denk daran, dass die WENNS-Funktion den Wert der ersten wahren Bedingung zurückgibt, auf die sie stößt. Hätten wir die Bedingungen in umgekehrter Reihenfolge geschrieben, hätten wir für den ersten Mitarbeiter einen Bonus von 200 berechnet, da der Ausdruck C2>=3 wahr ist. Die Formel würde also den zugehörigen Wert zurückgeben und die restlichen Kriterien nicht mehr prüfen.
Kopieren wir die Formel zur Berechnung des Bonus für den zweiten Mitarbeiter. Ändere die Formel in Zelle D3 der obigen Beispieltabelle wie folgt:
=WENNS(C3>=5; 1000; C3>=4; 500; C3>=3; 200; C3<3; 0)
Die Formel gibt nun den Wert 0 zurück. Die WENNS-Funktion wertet das erste Kriterium aus, C3>=5, das falsch ist. Anschließend wertet sie das zweite Kriterium aus, C3>=4, das ebenfalls falsch ist. Danach wertet sie das dritte Kriterium aus, C3>=3, das ebenfalls falsch ist. Schließlich prüft sie das letzte Kriterium, C3<3, das wahr ist, da der Wert in Zelle C3 kleiner als 3 ist. Da das letzte Kriterium wahr ist, gibt die Funktion den Endwert zurück, nämlich 0.
Springen wir mal zum letzten Mitarbeiter in der Liste und probieren wir die Formel an diesem Beispiel aus.
=WENNS(C6>=5; 1000; C6>=4; 500; C6>=3; 200; C6<3; 0)
In diesem Fall gibt deine Formel 1000 zurück. WENNS wertet das erste Kriterium, C6>=5, aus, kommt zu dem Schluss, dass es wahr ist, und gibt den ersten Wert\_if\_true zurück, nämlich 1000.
Fehler bei der WENNS-Funktion
Wie jede Funktion in Excel kann auch WENNS eine Reihe von Fehlern zurückgeben.
Die WENNS-Funktion gibt den Fehler „#WERT!“ zurück
Die WENNS-Funktion gibt den Fehler #WERT! zurück, wenn ein Bedingungsargument nicht als „wahr“ oder „falsch“ ausgewertet wird. Überprüfe jede Bedingung in der Formel noch einmal und stelle sicher, dass es sich um eine logische Aussage handelt, die als „wahr“ oder „falsch“ ausgewertet wird. Bei Bedarf kannst du dir die logischen Operatoren in Excel ansehen.
Die WENNS-Funktion gibt den Fehler „#N/A“ zurück
Die WENNS-Funktion gibt den Fehler #N/A zurück, wenn keine der logischen Bedingungen wahr ist. Nehmen wir zum Beispiel folgende Formel:
=WENNS(A1>5; "Big"; A1>2; "Small")
Diese Formel würde den Fehler #N/A zurückgeben, wenn der Wert in Zelle A1 kleiner oder gleich 2 ist, da keine der logischen Bedingungen in der Formel wahr ist.
Um diesen Fehler zu vermeiden, kannst du wie unten beschrieben einen Standardwert für die WENNS-Funktion festlegen.
Standardwert für die WENNS-Funktion
Wenn du möchtest, dass die WENNS-Funktion einen Standardwert zurückgibt, wenn keine der Bedingungen wahr ist, kannst du für die letzte Bedingung einfach TRUE eingeben, gefolgt von einem Endwert\_if\_true. Nimm das Beispiel, das wir zuvor verwendet haben:
=WENNS(A1>5; "Big"; A1>2; "Small")
Diese Formel gibt für jeden Wert kleiner oder gleich 2 den Fehler #N/A zurück, da keine der Bedingungen erfüllt wäre.
Fügen wir einen Standard-Rückgabewert hinzu:
=WENNS(A1>5; "Big"; A1>2; "Small"; WAHR; "Unknown")
Diese Formel wertet jede Bedingung aus und gelangt zur letzten Bedingung, wenn die ersten beiden Bedingungen falsch sind. Die letzte Bedingung ist WAHR, daher gibt die Formel standardmäßig „Unbekannt“ zurück, wenn keine anderen Bedingungen wahr sind.
Weiter zu den WENNS-Übungsaufgaben! →Verwendete Bilder
- https://excelexercises.com/logo2.png
- https://excelexercises.com/excel-functions/excelImages/logoGreenWhite.png